#compdef add-zsh-hook

local context state state_descr line
typeset -A opt_args

_add-zsh-hook_hooks() {
  if (( $+opt_args[-d] )); then
    _wanted functions expl "installed hooks" compadd -a - "$line[1]_functions" && return 0
  else
    _functions && return 0
  fi
  return 1
}

_add-zsh-hook() {
  _arguments -s -w -S : \
    '(-D)-d[remove HOOK from the array]' \
    '(-d)-D[interpret HOOK as pattern to remove from the array]' \
    {-U,-z,-k}"[passed to 'autoload']" \
    ':hook class:(chpwd precmd preexec periodic zshaddhistory zshexit zsh_directory_name)' \
    ':hook function:_add-zsh-hook_hooks'
}

_add-zsh-hook "$@"
