# Contributor: Edward E. <develinthedetail@gmail.com>
# source: https://github.com/msys2/MINGW-packages/blob/master/mingw-w64-libheif/PKGBUILD

_realname=libheif
pkgbase=mingw-w64-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}")
pkgver=1.20.1
pkgrel=1
pkgdesc="HEIF image decoder/encoder library and tools (mingw-w64)"
arch=('any')
mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clangarm64')
url="https://github.com/strukturag/libheif"
msys2_references=(
  "cpe: cpe:/a:struktur:libheif"
)
license=('spdx:LGPL-3.0 AND MIT')
makedepends=("${MINGW_PACKAGE_PREFIX}-cmake"
             "${MINGW_PACKAGE_PREFIX}-ninja"
             "${MINGW_PACKAGE_PREFIX}-gdk-pixbuf2"
             "${MINGW_PACKAGE_PREFIX}-cc")
depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs"
         "${MINGW_PACKAGE_PREFIX}-libde265"
         "${MINGW_PACKAGE_PREFIX}-x265")
source=("https://github.com/strukturag/libheif/releases/download/v${pkgver}/${_realname}-${pkgver}.tar.gz")
sha256sums=('55cc76b77c533151fc78ba58ef5ad18562e84da403ed749c3ae017abaf1e2090')

build() {
  mkdir -p "${srcdir}"/build-${MSYSTEM} && cd "${srcdir}"/build-${MSYSTEM}

  declare -a extra_config
  extra_config+=("-DCMAKE_BUILD_TYPE=Release")

  # Keep "-DX265_API_IMPORTS" flag due to https://github.com/strukturag/libheif/issues/357
  MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \
    ${MINGW_PREFIX}/bin/cmake \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \
      "${extra_config[@]}" \
      -DBUILD_SHARED_LIBS=ON \
      -DWITH_OPENJPH_DECODER=OFF \
      -DDWITH_OPENJPH_ENCODER=OFF \
      -DWITH_HEADER_COMPRESSION=OFF \
      -DWITH_LIBDE265=ON \
      -DWITH_LIBDE265_PLUGIN=OFF \
      -DWITH_X265=ON \
      -DWITH_X265_PLUGIN=OFF \
      -DWITH_AOM_DECODER=OFF \
      -DWITH_AOM_DECODER_PLUGIN=OFF \
      -DWITH_AOM_ENCODER=OFF \
      -DWITH_AOM_ENCODER_PLUGIN=OFF \
      -DWITH_RAV1E=OFF \
      -DWITH_RAV1E_PLUGIN=OFF \
      -DWITH_DAV1D=OFF \
      -DWITH_DAV1D_PLUGIN=OFF \
      -DWITH_SvtEnc=OFF \
      -DWITH_SvtEnc_PLUGIN=OFF \
      -DWITH_KVAZAAR=OFF \
      -DWITH_KVAZAAR_PLUGIN=OFF \
      -DWITH_FFMPEG_DECODER=OFF \
      -DWITH_FFMPEG_DECODER_PLUGIN=OFF \
      -DWITH_JPEG_DECODER=OFF \
      -DWITH_JPEG_ENCODER=OFF \
      -DWITH_OpenJPEG_DECODER=OFF \
      -DWITH_OpenJPEG_ENCODER=OFF \
      -DENABLE_PLUGIN_LOADING=OFF \
      -DWITH_LIBSHARPYUV=OFF \
      -DWITH_EXAMPLES=OFF \
      -DBUILD_TESTING=OFF \
      -DX265_CFLAGS="-DX265_API_IMPORTS" \
      ../${_realname}-${pkgver}

  ${MINGW_PREFIX}/bin/cmake --build .
}

package() {
  cd "${srcdir}"/build-${MSYSTEM}

  DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake --install .
}